Power Apps Canvas Coding Standards (Part 3)

Gallery Design Guidelines

Design Empty States

Empty States Examples

Reset The Gallery Scroll Position

powerappsCopy
// OnHidden property of a screen
Reset(GalleryName);

Refresh To Show Current Data

Refresh Button Example

Filter Large Datasets

Filter Dropdowns Example

powerappsCopy
// ITEMS property of a gallery with three dropdowns filters
Filter(
    'Paid Time Off',
    drp_Type.Selected.Value=Blank() Or TimeOffType=drp_Type.Selected.Value, 
    drp_Status.Selected.Value=Blank() Or Status=drp_Status.Selected.Value, 
    drp_Employee.Selected.Value=Blank() Or Employee=drp_Employee.Selected.Value
)

Define The Sort Order

Sorted Gallery Example

Do Not Show Live Updates for Search Results

powerappsCopy
// Items property of a searchable gallery connected to a text input
Search(Locations, txt_SearchLocation.Text, "Address", "City", "Province")

powerappsCopy
// OnSelect property of a search button
Set(gblSearchLocation, txt_SearchLocation.Text)

// Items property of a searchable gallery using a global variable
Search(Locations, gblSearchLocation, "Address", "City", "Province")

Avoid Nested Galleries

Nested Gallery Example

Use Flexible Height Galleries

Gallery Types

Error-Handling

Enable Formula-Level Error Management

Error Management Setting

Patch Function Error-Handling

powerappsCopy
// create a new invoice
If(
    IsError(
        Patch(
            'Invoices', 
            Defaults('Invoices'),
            {
                CustomerNumber: "C0001023", 
                InvoiceDate: Date(2022, 6, 13), 
                PaymentTerms: "Cash On Delivery", 
                TotalAmount: 13423.75
            }
        )
    ),
    // on failure
    Notify("Error: the invoice could not be created", NotificationType.Error),
    // on success 
    Navigate('Success Screen')
)

Power Apps Forms Error-Handling

powerappsCopy
// OnSelect property of the form's submit button
SubmitForm(frm_Invoice)

// OnSuccess property of the form
Navigate('Success Screen');

// OnFailure property of the form
Notify(
    "Error: the invoice could not be created", 
    NotificationType.Error
)

// Bad: OnSelect property of the form's submit button
SubmitForm(frm_Invoice)
Navigate('Success Screen');

Power Automate Flow Error-Handling

powerappsCopy
// Get customer invoices
If(
    IsError(
        GetAllCustomerInvoices.Run("C0001023")
    ),
    // On failure
    Notify("Error: could not retrieve customer invoices", NotificationType.Error),
    // On success 
    Navigate('Success Screen')
)

powerappsCopy
// calculate the percentage of tasks completed
IfError(
    gblTasksCompleted/gblTasksTotal, 
    0
)

Handling Unexpected Errors

powerappsCopy
// unexpected error notification message
Notify(
    Concatenate(
        "Error: " ,
        FirstError.Message, 
        "Kind: ", 
        FirstError.Kind,
        ", Observed: ",
        FirstError.Observed, 
        ", Source: ", 
        FirstError.Source
    ),
    NotificationType.Information
);

Optimizing App Performance

Load Multiple Datasets Concurrently

powerappsCopy
// Sequential code execution (slower)
Set(
    gblUserProfile, 
    Office365Users.GetUserProfileV2(User().Email)
);
ClearCollect(
    colActiveProjects, 
    Filter(
        Projects, 
        ProjectStatus.Value="Active"
    )
)

// Simultaneous code execution (faster)
Concurrent(
    // Thread #1
    Set(
        gblUserProfile, 
        Office365Users.GetUserProfileV2(User().Email)
    ),
    // Thread #2
    ClearCollect(
        colActiveProjects, 
        Filter(
            Projects, 
            ProjectStatus.Value="Active"
        )
    )
)

Write Formulas That Use Delegation

powerappsCopy
Filter(
    'Device Orders',
    'Device Orders (Views)'.'Active Device Orders'
)

Delegation Warning

Cache Data in Collections and Variables

powerappsCopy
// Store the currency exchange rates table in memory for quicker access
ClearCollect(
    colCurrencyExchangeRates, 
    'Currency Exchange Rates'
)

Limit The Size of Collections

powerappsCopy
// selecting only desired columns from the accounts table
ClearCollect(
    colAccounts 
    ShowColumns(
        Accounts, 
        "name",
        "city",
        "state", 
        "zipcode"
    )
)

"Batch Patch" Multiple Changes to a data source Table at Once

powerappsCopy
// collection of records to update
ClearCollect(
    colUpdateEmployees,
    Table(
        {ID: 2, FullName: "Alice Henderson", Active: true},
        {ID: 4, FullName: "David Wright", Active: false},
        {ID: 5, FullName: "Mary Allen", Active: false}
    )
);
// update records one-by-one (slower)
ForAll(
    colUpdateEmployees, 
    Patch(
        Employees,
        LookUp(Employees, ID=colUpdateEmployees[@ID]),
        {
            FullName: colUpdateEmployees[@FullName], 
            Active: colUpdateEmployees[@Active]
        }
    )
);
// bulk update multiple records at once (faster)
Patch(
    Employees, 
    ShowColumns(
        colUpdateEmployees, 
        "ID",
        "FullName", 
        "Active"
    )
);

Reduce Code in The On Start Property

Performance Analytics

Minimize Number of Controls On A Single Screen

Gallery for Repetitive Controls

Enable DelayOutput For Text Input Controls

DelayOutput Setting

Do Not Reference Controls On Other Screens

Improving Code Readability

Apply Automatic Formatting

Format Text Button

Use The WITH Function To Improve Readability

powerappsCopy
Value(txt_InterestRate.Text)/100 * Value(txt_LoanAmount.Text) /
(1 - (1 + Value(txt_InterestRate.Text)/100)^-Value(txt_NumberOfPayments.Text))

powerappsCopy
With(
    {
        InterestRate: Value(txt_InterestRate.Text)/100, 
        LoanAmount: Value(txt_LoanAmount.Text), 
        NumberOfPayments: Value(txt_NumberOfPayments.Text)
    },
    InterestRate * LoanAmount / (1 - (1 + InterestRate)^-NumberOfPayments)
);

Choose Consistent Logical Operators

powerappsCopy
ClearCollect(
    colCustomers,
    {State: "NY", Status: "Active"}
);

// And operator
Filter(
    colCustomers, 
    State = "NY"
    And Status="Active"
);

// And() function
Filter(
    colCustomers, 
    And(
        State = "NY", 
        Status="Active"
    )
);

// && operator
Filter(
    colCustomers, 
    State = "NY"
    && Status="Active"
)

Join Text Strings & Variables

powerappsCopy
// set variables
Set(gblUserName, User().FullName); 
Set(gblStreetAddress, "123 Chestnut Street");

// join text using the & operator
"Hi, my name is"&gblUserName&" and I live at "&gblStreetAddress&".";

// join text using the Concatenate function
Concatenate("Hi, my name is", gblUserName,"and I live at ",gblStreetAddress)&".";

// join text using $-Strings
$"Hi, my name is {gblUserName} and I live at {gblStreetAddress}"

Remove IF Statements When The Result Is A True Or False Value

powerappsCopy
// With IF Statement evaluates to true or false
If(gblUserRole="Manager" And gblIsDataLoaded=true, true, false)

// Without IF Statment evaluates to true or false
gblUserRole="Manager" And gblIsDataLoaded

Substitute The Self Operator for The Current Control Name

powerappsCopy
// Reference using the current control name
ColorFade(txt_SubmitForm.Fill, -10%)

// Reference using the Self operator
ColorFade(Self.Fill, -10%)

Flatten Nested IFs

powerappsCopy
Set(gblBankAccountBalance, 5000);
Set(gblDailyWithdrawlLimit, 1000);
Set(gblWithdrawlAmount, 100);

// Nested IFs
If(
    gblWithdrawlAmount > gblBankAccountBalance, 
    Notify("Insufficent funds", NotificationType.Error), 
    If(
        gblWithdrawlAmount > gblDailyWithdrawlLimit,
        Notify("Daily withdrawl limit exceeded", NotificationType.Error), 
        Notify("You have Withdrawn $"&gblWithdrawlAmount, NotificationType.Success)
    )
);

// Flattened IFs
If(
    gblWithdrawlAmount > gblBankAccountBalance, 
    Notify("Insufficent funds", NotificationType.Error), 
    gblWithdrawlAmount > gblDailyWithdrawlLimit,
    Notify("Daily withdrawl limit exceeded", NotificationType.Error), 
    Notify("You have withdrawn $"&gblWithdrawlAmount, NotificationType.Success)
);

Alphabetical Order in Patch & UpdateContext Functions

powerappsCopy
// create a new record
Patch(
    colContacts, 
    Defaults(colContacts),
    {
        Active: true,
        Address: "67 Walnut Grove", 
        Name: "Jane Smith", 
        PostalCode: "R2G 3V3", 
        Province: "Ontario"
    }
);

// update local variables
UpdateContext(
    {
        locAccountID: GUID(), 
        locBlockerUserInput: true, 
        locIsMenuVisible: false, 
        locReadOnlyMode: false, 
        locSelectedProperty: "Location"
    }
);

Simplify Logical Comparisons When Evaluating a Boolean

powerappsCopy
Set(gblIsBankAccountActive, true);

// logical comparison
If(
    gblIsBankAccountActive=true, 
    Navigate('Withdraw Funds Screen'),
    Notify("Bank account is not active", NotificationType.Error)
);

// boolean value only
If(
    gblIsBankAccountActive, 
    Navigate('Withdraw Funds Screen'),
    Notify("Bank account is not active", NotificationType.Error)
)

Handle Errors Gracefully

Keep It Simple and Efficient

"Well-formatted code has two benefits. It is easier to read and quicker to spot mistakes." - Power Apps Coding Standards

Best Practices for Power Apps Development

1. Delegation and Performance: Always delegate where possible.
2. Error Management: Enable formula-level handling.
3. Theming Consistency: Use variables or templates.
4. Code Readability: Format, flatten, and simplify.
5. Testing: Use tools, peers, and UAT.

Continuous Improvement